name='python3-pygments'
version='2.18.0'
release='1'
desc='Python syntax highlighter'
homepage='https://pygments.org/'
maintainer="Евгений Храмов <xpamych@yandex.ru>"
architectures=('all')
license=('BSD-2-Clause')
provides=('pygmentize')
conflicts=('pygmentize')

deps=(
  'python'
)

build_deps=(
  'python3-setuptools'
  'python3-sphinx'
  'python3-wcag-contrast-ratio'
  'python3-build'
  'python3-installer'
  'python3-wheel'
  'python3-hatchling'
  'python3-pytest'
  'python3-lxml'
)
build_deps_almalinux=(
  'python3-setuptools'
  'python3-sphinx'
  'python3-wcag-contrast-ratio'
  'python3-build'
  'python3-installer'
  'python3-setuptools-wheel'
  'python3-hatchling'
  'python3-pytest'
  'python3-lxml'
)

sources=("https://pypi.org/packages/source/p/pygments/pygments-$version.tar.gz")
checksums=('SKIP')

build() {
  cd pygments-$version
  python -m build --wheel --no-isolation
  make -C doc html
}

check() {
  cd pygments-$version
  PYTHONDONTWRITEBYTECODE=1 pytest
}

package() {
  cd pygments-$version

  python -m installer --destdir="$pkgdir" dist/*.whl
  install-license LICENSE ./python3-pygments/LICENSE

  mkdir -p "$pkgdir/usr/share/doc"
  cp -rT doc/_build/html "$pkgdir/usr/share/doc/$name"
  install -Dm644 doc/pygmentize.1 -t "$pkgdir/usr/share/man/man1"
  install -Dm644 external/pygments.bashcomp \
    "$pkgdir/usr/share/bash-completion/completions/pygmentize"
}