name='qmk-cli'
version='1.1.5'
release='1'
desc='CLI tool for customizing supported mechanical keyboards.'
homepage='https://github.com/qmk/qmk_cli'
maintainer="Евгений Храмов <xpamych@yandex.ru>"
architectures=('amd64')
license=('MIT')
provides=('qmk')
conflicts=('qmk' 'qmk-git')

deps=(
    'arm-none-eabi-binutils-cs'
    'arm-none-eabi-gcc-cs'
    'arm-none-eabi-newlib'
    'avr-binutils'
    'avr-gcc'
    'avr-libc'
    'avrdude'
    'clang'
    'dfu-programmer'
    'dfu-util'
    'diffutils'
    'flake8'
    'gcc'
    'git'
    'libusb-compat'
    'python-dotty-dict'
    'python-hidapi'
    'python-hjson'
    'python-jsonschema'
    'python-milc'
    'python-pyusb'
    'unzip'
    'wget'
    'zip'
)
build_deps=(
    'python'
    'python3-build'
    'python3-pip'
)

sources=("git+https://github.com/qmk/qmk_cli.git"
         "https://raw.githubusercontent.com/qmk/qmk_firmware/master/util/udev/50-qmk.rules")
checksums=('SKIP'
'SKIP')

build() {
    cd "${srcdir}/qmk_cli"
    python -m build --skip-dependency-check --wheel
}

package() {
    cd "${srcdir}/qmk_cli"
    PIP_CONFIG_FILE=/dev/null pip install --isolated --root="$pkgdir" --ignore-installed --no-deps dist/*.whl
    python -O -m compileall "${pkgdir}"

    install-license ./LICENSE ${name}/LICENSE
    install -d "${pkgdir}/usr/lib/udev/rules.d"
    install -Dm644 "${srcdir}/50-qmk.rules" "${pkgdir}/usr/lib/udev/rules.d/50-qmk.rules"
}