name='gamemode-lib32'
version='1.8.1'
release='1'
desc='A daemon/lib combo that allows games to request a set of optimisations be temporarily applied to the host OS'
homepage='https://github.com/FeralInteractive/gamemode'
maintainer="Евгений Храмов <xpamych@yandex.ru>"
architectures=('amd64')
license=('BSD-3-Clause')
provides=('gamemode')
conflicts=('gamemode' 'gamemode-bin' 'gamemode-git')

deps=(
  'lib32-dbus'
  'lib32-glibc'
  'lib32-systemd'
)
deps_arch=(
  'lib32-dbus'
  'lib32-glibc'
  'lib32-systemd'

)
build_deps=(
  'git'
  'meson'
  'appstream'
)

sources=("git+https://github.com/FeralInteractive/gamemode.git#tag=v${version}")
checksums=('SKIP')

build() {
  cd ${srcdir}
  export CC='gcc -m32'
  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
  meson gamemode build --libdir /usr/lib32 -Dwith-examples=false -Dwith-sd-bus-provider=no-daemon -Dwith-util=false
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
  rm -rf "${pkgdir}"/{etc,usr/include}
  install -dm 755 "${pkgdir}"/usr/share/licenses
  ln -s gamemode "${pkgdir}"/usr/share/licenses/lib32-gamemode
}