name='icu'
version='75.1'
release='4'
desc='International Components for Unicode library.'
homepage='https://icu.unicode.org'
maintainer="Евгений Храмов <xpamych@yandex.ru>"
architectures=('amd64')
license=(
  'LicenseRef-Unicode-3.0'
  'BSD-2-Clause'
  'BSD-3-Clause'
)
provides=(libicu{data,i18n,io,test,tu,uc}.so)
conflicts=(libicu{data,i18n,io,test,tu,uc}.so)

deps=(
  'libgcc'
  'glibc'
)

build_deps=('python')

sources=("https://github.com/unicode-org/icu/releases/download/release-${version//./-}/icu4c-${version//./_}-src.tgz")
checksums=('SKIP')

prepare() {
  cd icu/source
  # Required fix for thunderbird 115 to show Calendar and sidebar properly
  # https://bugzilla.mozilla.org/show_bug.cgi?id=1843007
  # https://unicode-org.atlassian.net/browse/ICU-22132
  patch -Np1 < "${scriptdir}/ICU-22132.patch"
}

build() {
  cd icu/source
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
	--sbindir=/usr/bin
  make
}

check() {
  cd icu/source
  make check
}

package() {
  cd icu/source
  make DESTDIR="${pkgdir}" install

  install-license "${scriptdir}"/LICENSE ./${name}/LICENSE
}