name='python3-milc'
version='1.9.1'
release='2'
desc='Opinionated Batteries-Included Python 3 CLI Framework.'
desc_ru='Фреймворк Python 3 для создания CLI-приложений'
homepage='https://milc.clueboard.co/'
maintainer='Evgeny Khramov <xpamych@yandex.ru>'
maintainer_ru='Евгений Храмов <xpamych@yandex.ru>'
architectures=('all')
license=('MIT')
provides=('milc-color')
conflicts=('milc-color')

deps=(
    'python3'
    'python3-appdirs'
    'python3-argcomplete'
    'python3-colorama'
    'python3-halo'
)

deps_alt=(
    'python3'
    'python3-module-appdirs'
    'python3-module-argcomplete'
    'python3-module-colorama'
    'python3-module-halo'
)
deps_arch=(
    'python'
    'python-appdirs'
    'python-argcomplete'
    'python-colorama'
    'python-halo'
)
deps_debian=(
    'python3'
    'python3-appdirs'
    'python3-argcomplete'
    'python3-colorama'
    'python3-halo'
)
deps_fedora=("${deps[@]}")
deps_redos=("${deps[@]}")
deps_rhel=("${deps[@]}")
deps_rosa=("${deps[@]}")

build_deps=('python3-setuptools')

build_deps_alt=('python3-module-setuptools')
build_deps_arch=('python-setuptools')
build_deps_debian=('python3-setuptools')
build_deps_fedora=("${build_deps[@]}")
build_deps_redos=("${build_deps[@]}")
build_deps_rhel=("${build_deps[@]}")
build_deps_rosa=("${build_deps[@]}")

sources=("https://github.com/clueboard/milc/archive/${version}.tar.gz")
checksums=('SKIP')

build() {
    cd "milc-${version}"
    python setup.py build
}

check() {
    cd "milc-${version}"
    rm tests/test_script*.py
    nose2
}

package() {
    cd "milc-${version}"
    python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${name}/LICENSE"
}

files() {
    files-find "./usr/lib/python3.*/site-packages/milc"
    files-find "./usr/lib/python3.*/site-packages/milc-*.egg-info"
    files-find-share "licenses"
}