name='gitea'
version='1.22.3'
release='1'
desc='Painless self-hosted Git service, community managed.'
homepage='https://gitea.io'
maintainer="Евгений Храмов <xpamych@yandex.ru>"
architectures=('amd64')
license=('MIT')
provides=('gitea')
conflicts=('gitea' 'gitea-git')

deps=(
  'git'
)

build_deps=(
  'go'
  'nodejs'
  'npm'
  'python3-poetry'
  'openssh'
  'pam-devel'
)

opt_deps=(
  'mariadb: поддержка MariaDB'
  'memcached: поддержка MemCached'
  'openssh: поддержка GIT поверх SSH'
  'pam: поддержка аутентификации с помощью PAM'
  'postgresql: поддержка PostgreSQL'
  'redis: поддержка Redis'
  'sqlite: поддержка SQLite'
)

sources=("git+https://github.com/go-gitea/gitea.git#tag=v${version}")
checksums=('SKIP')

options=(!lto)
backup=('etc/gitea/app.ini')

prepare() {
  cd ${name}
  # Patch to disable failing tests that rely on weak ssh keys (DSA-1024)
  # See https://github.com/go-gitea/gitea/issues/31624
  make deps
}

build() {
  cd ${name}
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export EXTRA_GOFLAGS="-buildmode=pie -mod=readonly -modcacherw"
  export LDFLAGS="-linkmode=external -compressdwarf=false -X 'code.gitea.io/gitea/modules/setting.AppWorkPath=/var/lib/gitea/' -X 'code.gitea.io/gitea/modules/setting.CustomConf=/etc/gitea/app.ini'"
  export TAGS="bindata sqlite sqlite_unlock_notify pam"
  make -j$(nproc)
}

check() {
  cd ${name}
  make test
}

package() {
  install-binary ${name}/${name}
  install-license ${name}/LICENSE ./$name/LICENSE
  install-systemd ${scriptdir}/${name}.service
  install -Dm644 ${scriptdir}/${name}.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/${name}.conf
  install -Dm644 ${scriptdir}/${name}.sysusers "${pkgdir}"/usr/lib/sysusers.d/${name}.conf
  install -Dm644 ${name}/custom/conf/app.example.ini "${pkgdir}"/etc/gitea/app.ini
}