name='firefox-bin'
version='136.0.2'
ver='136.0.2'
release='1'
desc='Fast, Private & Safe Web Browser.'
homepage='https://www.mozilla.org/firefox/'
maintainer="Евгений Храмов <xpamych@yandex.ru>"
architectures=('amd64')
license=('MPL' 'GPL' 'LGPL')
provides=('firefox')
conflicts=('firefox' 'firefox-git')

deps=('gtk3'
      'libXt'
      'mailcap'
      'dbus-glib'
      'nss'
)

deps_debian=('libgtk-3-dev'
             'libxt6'
             'mailcap'
             'libdbus-glib-1-2'
             'libnss3'
)

opt_deps=('ffmpeg: H264/AAC/MP3 decoding'
          'NetworkManager: Location detection via available WiFi networks'
          'libnotify: Notification integration'
          'speech-dispatcher: Text-to-Speech'
          'hunspell-en-US: Spell checking, American English'
          'hunspell-ru: Spell checking, Russian'
)

opt_deps_debian=('ffmpeg: H264/AAC/MP3 decoding'
          'network-manager: Location detection via available WiFi networks'
          'libnotify-bin: Notification integration'
          'speech-dispatcher: Text-to-Speech'
          'hunspell-en-us: Spell checking, American English'
          'hunspell-ru: Spell checking, Russian'
)

sources=("https://download.mozilla.org/?product=firefox-${ver}&os=linux64&lang=ru")
checksums=('SKIP')

options=(!strip)

package() {
  cd $srcdir
  # Create directories
  mkdir -p "$pkgdir"/usr/bin
  mkdir -p "$pkgdir"/usr/share/applications
  mkdir -p "$pkgdir"/opt

  # Install
  cp -r firefox/ "$pkgdir"/opt/$name

  # Launchers
  install -m755 $scriptdir/firefox.sh "$pkgdir"/usr/bin/firefox

  # Desktops
  install -m644 $scriptdir/*.desktop "$pkgdir"/usr/share/applications/

  # Icons
  for i in 16x16 32x32 48x48 64x64 128x128; do
    install -d "$pkgdir"/usr/share/icons/hicolor/$i/apps/
    ln -s /opt/$name/browser/chrome/icons/default/default${i/x*}.png \
          "$pkgdir"/usr/share/icons/hicolor/$i/apps/firefox.png
  done

  # Configure dictionaries and certificates
  ln -Ts /usr/share/hunspell "$pkgdir"/opt/$name/dictionaries
  ln -Ts /usr/share/hyphen "$pkgdir"/opt/$name/hyphenation
  ln -sf /usr/lib/libnssckbi.so "$pkgdir"/opt/$name/libnssckbi.so

  # Disable update checks
  mkdir "$pkgdir"/opt/$name/distribution
  install -m644 $scriptdir/policies.json "$pkgdir"/opt/$name/distribution/
}